Pertanyaan Implementasi Fibonacci dalam perakitan memberikan hasil yang tidak diharapkan


Saya mencoba menulis versi kode assembly Fibonacci yang memberikan nomor Fibonacci n dan mengembalikannya.

Untuk beberapa alasan itu mengalami kesulitan menyimpan nilai kembalinya angka Fibonacci dan menambahkannya.

Saya ingin mencetak angka Fibonacci ke-n.

Saya telah membuat beberapa modifikasi pada kode saya, sekarang masih salah, tetapi lebih dekat. Sekarang ini memberi tahu saya bahwa angka Fibonacci ke-11 adalah 48. Masih tidak benar, tetapi kita mendapatkan suatu tempat yang benar?

.text

    .globl _fibonacci
_fibonacci:
    pushl %ebp
    movl %esp,%ebp
    push %esi
    movl 8(%ebp),%esi

    cmp $1,%esi
    jle BASE
    sub $1,%esi
    push %esi
    call _fibonacci
    add $4,%esp
    movl %eax,%edx
    sub $1,%esi
    push %esi
    call _fibonacci
    add $4,%esp
    add %eax,%edx
    movl %edx,%eax

DONE:
    pop %esi
    pop %ebp
    ret

BASE:
    mov $1,%eax
    jmp DONE

Saya menyebut kode assembly ini menggunakan C:

#include <stdio.h>

int fibonacci(int n);

int main(void){
  int n=111;
  int x=fibonacci(n);
  printf("The %d fibonaacci number is %d\n",n,x);
}

4
2017-10-22 23:50


asal


Jawaban:


Masalahnya adalah Anda harus lebih berhati-hati dengan penggunaan daftar di seluruh panggilan rekursif.

Kode Anda menganggap itu %edx mempertahankan nilainya di panggilan kedua.

Namun, ini tidak terjadi, karena _fibonacci mengubahnya.


1
2017-10-23 00:37



Panggilan rekursif Anda sedang naik daun %edx. Kamu butuh pushl %edx dalam prolog dan popl %edx di postlog Anda, seperti:

.text

    .globl _fibonacci
/* fib(n) = fib(n-1) + fib(n-2) */
_fibonacci:
    pushl %ebp
    movl %esp,%ebp
    pushl %esi
    pushl %edx  /* <-- PUSH TO SAVE BEFORE CLOBBERING */
    movl 8(%ebp),%esi

    /* 0th and 1st numbers are defined to be 1. */
    cmpl $1,%esi
    jle BASE

    /* find fib(n-1) */
    subl $1,%esi
    pushl %esi
    call _fibonacci

    addl $4,%esp
    movl %eax,%edx  /* <-- %edx CLOBBERED! */

    /* find fib(n-2) */
    subl $1,%esi
    pushl %esi
    call _fibonacci

    addl $4,%esp
    addl %edx,%eax

DONE:
    popl %edx  /* <-- POP TO RESTORE AFTER CLOBBERING */
    popl %esi
    popl %ebp
    ret

BASE:
    movl $1,%eax
    jmp DONE

Menggunakan driver ini:

// BUILD -arch i386 ONLY
// clang -arch i386 fib.s fibo.c -o fibo
#include <stdio.h>

int fibonacci(int n);

void Test(int i) {
  int r = fibonacci(i);
  printf("fib(%d) -> %d\n", i, r);
}

int main(void){
  for (int i = 0; i < 10; ++i) {
    Test(i);
  }
  return 0;
}

Uji coba terlihat seperti:

$ ./fibo 
fib(0) -> 1
fib(1) -> 1
fib(2) -> 2
fib(3) -> 3
fib(4) -> 5
fib(5) -> 8
fib(6) -> 13
fib(7) -> 21
fib(8) -> 34
fib(9) -> 55

2
2017-10-23 00:46