Pertanyaan skrip perl untuk beralih ke simpul xml menggunakan XML :: LibXML


Saya mencoba untuk datang dengan skrip perl untuk beralih ke beberapa node dan mendapatkan nilai dalam file xml.

File XML saya terlihat seperti di bawah ini dan disimpan spec.xml

<?xml version="1.0" encoding="UTF-8"?>
<WO xmlns="http://www.example.com/yyyy" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" >
  <WOSet>
    <SR>
     <FINISHTIME>2013-07-29T18:21:38-05:00</FINISHTIME>
     <STARTTIME xsi:nil="true" />
     <TYPE>SR</TYPE>
     <DESCRIPTION>Create CUST</DESCRIPTION>
     <EXTERNALSYSTEMID />
     <REPORTEDBY>PCAUSR</REPORTEDBY>
     <REPORTEDEMAIL />
     <STATUS>RESOLVED</STATUS>
     <SRID>1001</SRID>
     <UID>1</UID>
     <SPEC>
       <AVALUE>IT</AVALUE>
       <ATTRID>CUST_DEPT</ATTRID>
       <NALUE xsi:nil="true" />
       <TVALUE />
     </SPEC>
     <SPEC>
       <AVALUE>001</AVALUE>
       <ATTRID>DEPT_CODE</ATTRID>
       <NVALUE xsi:nil="true" />
       <TVALUE />
     </SPEC>
  </SR>
</WOSet>
  </WO> 

ketika saya menjalankan skrip di bawah ini, saya tidak mendapatkan output maupun kesalahan untuk mendapatkan petunjuk tentang di mana memperbaiki hal-hal ...

Saya bukan ahli perl, akan suka ahli di sini untuk melalui beberapa cahaya ...

#!/usr/bin/perl
use XML::LibXML;
use strict;
use warnings;
my $file = 'spec.xml';
my $parser = XML::LibXML->new();
my $tree = $parser->parse_file($file);
my $root = $tree->getDocumentElement;

foreach my $atrid ( $tree->findnodes('WO/WOSet/SR/SPEC') ) {
    my $name =  $atrid->findvalue('ATTRID');
    my $value =  $atrid->findvalue('AVALUE');
    print $name
    print " = ";
    print $value;
    print ";\n";
}

Output yang saya harapkan adalah

 CUST_DEPT = IT
DEPT_CODE = 001

4
2017-10-02 15:16


asal


Jawaban:


XML tidak mengandung elemen apa pun yang bernama WO di ruang nama null. Anda ingin mencocokkan elemen yang dinamai WO dalam http://www.example.com/yyyy ruang nama.

#!/usr/bin/perl

use strict;
use warnings;

use XML::LibXML               qw( );
use XML::LibXML::XPathContext qw( );

my $file = 'spec.xml';

my $parser = XML::LibXML->new();
my $doc = $parser->parse_file($file);
my $root = $doc->getDocumentElement;

my $xpc = XML::LibXML::XPathContext->new($doc);
$xpc->registerNs(y => 'http://www.example.com/yyyy');

for my $atrid ( $xpc->findnodes('y:WO/y:WOSet/y:SR/y:SPEC') ) {
    my $name  = $xpc->findvalue('y:ATTRID', $atrid);
    my $value = $xpc->findvalue('y:AVALUE', $atrid);
    print "$name = $value\n";
}

5
2017-10-02 15:32